Move example contracts into new examples dir

4 files changed, 357 insertions, 0 deletions

diff --git a/packages/contracts/src/2.0.0/examples/ExchangeWrapper/ExchangeWrapper.sol b/packages/contracts/src/2.0.0/examples/ExchangeWrapper/ExchangeWrapper.sol
new file mode 100644
index 000000000..2fa0e3c5e
--- /dev/null
+++ b/packages/contracts/src/2.0.0/examples/ExchangeWrapper/ExchangeWrapper.sol
@@ -0,0 +1,100 @@
+/*
+
+  Copyright 2018 ZeroEx Intl.
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+    http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+
+*/
+
+pragma solidity 0.4.24;
+pragma experimental ABIEncoderV2;
+
+import "../../protocol/Exchange/interfaces/IExchange.sol";
+import "../../protocol/Exchange/libs/LibOrder.sol";
+
+
+contract ExchangeWrapper {
+
+    // Exchange contract.
+    // solhint-disable-next-line var-name-mixedcase
+    IExchange internal EXCHANGE;
+
+    constructor (address _exchange)
+        public
+    {
+        EXCHANGE = IExchange(_exchange);
+    }
+
+    /// @dev Cancels all orders created by sender with a salt less than or equal to the targetOrderEpoch
+    ///      and senderAddress equal to this contract.
+    /// @param targetOrderEpoch Orders created with a salt less or equal to this value will be cancelled.
+    /// @param salt Arbitrary value to gaurantee uniqueness of 0x transaction hash.
+    /// @param makerSignature Proof that maker wishes to call this function with given params.
+    function cancelOrdersUpTo(
+        uint256 targetOrderEpoch,
+        uint256 salt,
+        bytes makerSignature
+    )
+        external
+    {
+        address makerAddress = msg.sender;
+
+        // Encode arguments into byte array.
+        bytes memory data = abi.encodeWithSelector(
+            EXCHANGE.cancelOrdersUpTo.selector,
+            targetOrderEpoch
+        );
+
+        // Call `cancelOrdersUpTo` via `executeTransaction`.
+        EXCHANGE.executeTransaction(
+            salt,
+            makerAddress,
+            data,
+            makerSignature
+        );
+    }
+
+    /// @dev Fills an order using `msg.sender` as the taker.
+    /// @param order Order struct containing order specifications.
+    /// @param takerAssetFillAmount Desired amount of takerAsset to sell.
+    /// @param salt Arbitrary value to gaurantee uniqueness of 0x transaction hash.
+    /// @param orderSignature Proof that order has been created by maker.
+    /// @param takerSignature Proof that taker wishes to call this function with given params.
+    function fillOrder(
+        LibOrder.Order memory order,
+        uint256 takerAssetFillAmount,
+        uint256 salt,
+        bytes memory orderSignature,
+        bytes memory takerSignature
+    )
+        public
+    {
+        address takerAddress = msg.sender;
+
+        // Encode arguments into byte array.
+        bytes memory data = abi.encodeWithSelector(
+            EXCHANGE.fillOrder.selector,
+            order,
+            takerAssetFillAmount,
+            orderSignature
+        );
+
+        // Call `fillOrder` via `executeTransaction`.
+        EXCHANGE.executeTransaction(
+            salt,
+            takerAddress,
+            data,
+            takerSignature
+        );
+    }
+}
diff --git a/packages/contracts/src/2.0.0/examples/Validator/Validator.sol b/packages/contracts/src/2.0.0/examples/Validator/Validator.sol
new file mode 100644
index 000000000..72ed528ba
--- /dev/null
+++ b/packages/contracts/src/2.0.0/examples/Validator/Validator.sol
@@ -0,0 +1,56 @@
+/*
+
+  Copyright 2018 ZeroEx Intl.
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+    http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+
+*/
+
+pragma solidity 0.4.24;
+
+import "../../protocol/Exchange/interfaces/IValidator.sol";
+
+
+contract Validator is 
+    IValidator
+{
+
+    // The single valid signer for this wallet.
+    // solhint-disable-next-line var-name-mixedcase
+    address internal VALID_SIGNER;
+
+    /// @dev constructs a new `Validator` with a single valid signer.
+    /// @param validSigner The sole, valid signer.
+    constructor (address validSigner) public {
+        VALID_SIGNER = validSigner;
+    }
+
+    /// @dev Verifies that a signature is valid. `signer` must match `VALID_SIGNER`.
+    /// @param hash Message hash that is signed.
+    /// @param signerAddress Address that should have signed the given hash.
+    /// @param signature Proof of signing.
+    /// @return Validity of signature.
+    // solhint-disable no-unused-vars
+    function isValidSignature(
+        bytes32 hash,
+        address signerAddress,
+        bytes signature
+    )
+        external
+        view
+        returns (bool isValid)
+    {
+        return (signerAddress == VALID_SIGNER);
+    }
+    // solhint-enable no-unused-vars
+}
diff --git a/packages/contracts/src/2.0.0/examples/Wallet/Wallet.sol b/packages/contracts/src/2.0.0/examples/Wallet/Wallet.sol
new file mode 100644
index 000000000..b75021a31
--- /dev/null
+++ b/packages/contracts/src/2.0.0/examples/Wallet/Wallet.sol
@@ -0,0 +1,65 @@
+/*
+
+  Copyright 2018 ZeroEx Intl.
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+    http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+
+*/
+
+pragma solidity 0.4.24;
+
+import "../../protocol/Exchange/interfaces/IWallet.sol";
+import "../../utils/LibBytes/LibBytes.sol";
+
+
+contract Wallet is 
+    IWallet
+{
+    using LibBytes for bytes;
+
+    // The owner of this wallet.
+    // solhint-disable-next-line var-name-mixedcase
+    address internal WALLET_OWNER;
+
+    /// @dev constructs a new `Wallet` with a single owner.
+    /// @param walletOwner The owner of this wallet.
+    constructor (address walletOwner) public {
+        WALLET_OWNER = walletOwner;
+    }
+
+    /// @dev Validates an EIP712 signature.
+    ///      The signer must match the owner of this wallet.
+    /// @param hash Message hash that is signed.
+    /// @param eip712Signature Proof of signing.
+    /// @return Validity of signature.
+    function isValidSignature(
+        bytes32 hash,
+        bytes eip712Signature
+    )
+        external
+        view
+        returns (bool isValid)
+    {
+        require(
+            eip712Signature.length == 65,
+            "LENGTH_65_REQUIRED"
+        );
+
+        uint8 v = uint8(eip712Signature[0]);
+        bytes32 r = eip712Signature.readBytes32(1);
+        bytes32 s = eip712Signature.readBytes32(33);
+        address recoveredAddress = ecrecover(hash, v, r, s);
+        isValid = WALLET_OWNER == recoveredAddress;
+        return isValid;
+    }
+}
diff --git a/packages/contracts/src/2.0.0/examples/Whitelist/Whitelist.sol b/packages/contracts/src/2.0.0/examples/Whitelist/Whitelist.sol
new file mode 100644
index 000000000..60cac26ea
--- /dev/null
+++ b/packages/contracts/src/2.0.0/examples/Whitelist/Whitelist.sol
@@ -0,0 +1,136 @@
+/*
+
+  Copyright 2018 ZeroEx Intl.
+
+  Licensed under the Apache License, Version 2.0 (the "License");
+  you may not use this file except in compliance with the License.
+  You may obtain a copy of the License at
+
+    http://www.apache.org/licenses/LICENSE-2.0
+
+  Unless required by applicable law or agreed to in writing, software
+  distributed under the License is distributed on an "AS IS" BASIS,
+  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+  See the License for the specific language governing permissions and
+  limitations under the License.
+
+*/
+
+pragma solidity 0.4.24;
+pragma experimental ABIEncoderV2;
+
+import "../../protocol/Exchange/interfaces/IExchange.sol";
+import "../../protocol/Exchange/libs/LibOrder.sol";
+import "../../utils/Ownable/Ownable.sol";
+
+
+contract Whitelist is
+    Ownable
+{
+
+    // Mapping of address => whitelist status.
+    mapping (address => bool) public isWhitelisted;
+
+    // Exchange contract.
+    // solhint-disable var-name-mixedcase
+    IExchange internal EXCHANGE;
+    bytes internal TX_ORIGIN_SIGNATURE;
+    // solhint-enable var-name-mixedcase
+
+    byte constant internal VALIDATOR_SIGNATURE_BYTE = "\x06";
+
+    constructor (address _exchange)
+        public
+    {
+        EXCHANGE = IExchange(_exchange);
+        TX_ORIGIN_SIGNATURE = abi.encodePacked(address(this), VALIDATOR_SIGNATURE_BYTE);
+    }
+
+    /// @dev Adds or removes an address from the whitelist.
+    /// @param target Address to add or remove from whitelist.
+    /// @param isApproved Whitelist status to assign to address.
+    function updateWhitelistStatus(
+        address target,
+        bool isApproved
+    )
+        external
+        onlyOwner
+    {
+        isWhitelisted[target] = isApproved;
+    }
+
+    /// @dev Verifies signer is same as signer of current Ethereum transaction.
+    ///      NOTE: This function can currently be used to validate signatures coming from outside of this contract.
+    ///      Extra safety checks can be added for a production contract.
+    /// @param signerAddress Address that should have signed the given hash.
+    /// @param signature Proof of signing.
+    /// @return Validity of order signature.
+    // solhint-disable no-unused-vars
+    function isValidSignature(
+        bytes32 hash,
+        address signerAddress,
+        bytes signature
+    )
+        external
+        view
+        returns (bool isValid)
+    {
+        // solhint-disable-next-line avoid-tx-origin
+        return signerAddress == tx.origin;
+    }
+    // solhint-enable no-unused-vars
+
+    /// @dev Fills an order using `msg.sender` as the taker.
+    ///      The transaction will revert if both the maker and taker are not whitelisted.
+    ///      Orders should specify this contract as the `senderAddress` in order to gaurantee
+    ///      that both maker and taker have been whitelisted.
+    /// @param order Order struct containing order specifications.
+    /// @param takerAssetFillAmount Desired amount of takerAsset to sell.
+    /// @param salt Arbitrary value to gaurantee uniqueness of 0x transaction hash.
+    /// @param orderSignature Proof that order has been created by maker.
+    function fillOrderIfWhitelisted(
+        LibOrder.Order memory order,
+        uint256 takerAssetFillAmount,
+        uint256 salt,
+        bytes memory orderSignature
+    )
+        public
+    {
+        address takerAddress = msg.sender;
+
+        // This contract must be the entry point for the transaction.
+        require(
+            // solhint-disable-next-line avoid-tx-origin
+            takerAddress == tx.origin,
+            "INVALID_SENDER"
+        );
+
+        // Check if maker is on the whitelist.
+        require(
+            isWhitelisted[order.makerAddress],
+            "MAKER_NOT_WHITELISTED"
+        );
+
+        // Check if taker is on the whitelist.
+        require(
+            isWhitelisted[takerAddress],
+            "TAKER_NOT_WHITELISTED"
+        );
+
+        // Encode arguments into byte array.
+        bytes memory data = abi.encodeWithSelector(
+            EXCHANGE.fillOrder.selector,
+            order,
+            takerAssetFillAmount,
+            orderSignature
+        );
+
+        // Call `fillOrder` via `executeTransaction`.
+        EXCHANGE.executeTransaction(
+            salt,
+            takerAddress,
+            data,
+            TX_ORIGIN_SIGNATURE
+        );
+    }
+}